ADCMP553 LTSpice Model

Hello,

There was no model developed for ADCMP553 but we have available BETA models for newer parts.
For example, ADCMP572. This is a Ultrafast comparator that is single-supply and is PECL compatible.

See below BETA Model:


* ADCMP573 SPICE Macro-Model Typical Values
* Description: COMPARATOR
* Generic Desc: Ultrafast 3.3V/5V Single Supply SiGe Comparator
* Developed by: JAV/ADGT
* Revision History: 6/8/2018- BETA
* Copyright 2018 by Analog Devices, Inc.
*
* Refer to www.analog.com/.../ADCMP572_573.pdf
*
* BEGIN Notes:
* This is a BETA Model only
*
* Not Modeled:
*
* Parameters modeled include:
*
* END Notes
*
* Node assignments
* non-inverting input
* | inverting input
* | | positive supply
* | | | negative supply
* | | | | Latch
* | | | | |
* | | | | | Q
* | | | | | | QNOT NINT INT GND
* | | | | | | |
.SUBCKT ADCMP573_new Vp Vtp Vn Vtn Vcci GND Latch Q QNOT Vcco
*
* INPUT STAGE
*
*
Q1 4 3 5 PIX
Q2 6 Vn 5 PIX
IBIAS Vcci 5 800E-6
RC1 4 GND 1E3
RC2 6 GND 1E3
CL1 4 6 3E-13
CIN Vp Vn 3E-15
VCM1 Vcci 7 1.9
D1 5 7 DX
EOS 3 Vp POLY(1) (31,98) 1E-3 1
Rterm1 Vp Vtp 50
Rterm2 Vn Vtn 50
*
* Reference Voltages
*
EREF 98 0 POLY(2) (Vcci,0) (GND,0) 0 0.5 0.5
RREF 98 0 100E3
*
* CMRR=66dB, ZERO AT 1kHz
*
ECM1 30 98 POLY(2) (Vp,98) (Vn,98) 0 0.5 0.5
RCM1 30 31 10E3
RCM2 31 98 5
CCM1 30 31 15.9E-12
*
* Latch Section
*
RX Latch GND 100E3
E1 10 98 (4,6) 1
S1 10 11 (Latch,GND) SLATCH1
R2 11 12 1
C3 12 98 5.4E-12
E2 13 98 (12,98) 1
R3 12 13 500
*
* Power Supply Section
*
GSY1 Vcci 52 POLY(1) (Vcci,GND) 4E-3 -2.6E-4
GSY2 52 GND POLY(1) (Vcci,GND) 3.7E-3 -.6E-3
RSY 52 GND 10
*
* Gain Stage Av=2GND fp=100MHz
*
G2 98 20 (12,98) 0.25
R1 20 98 1000
C1 20 98 10E-13
E3 97 0 (Vcci,0) 1
E4 52 0 (GND,0) 1
V1 97 21 DC 0.8
V2 22 52 DC 0.8
D2 20 21 DX
D3 22 20 DX
*
* Q Output
*
Q3 Vcco 41 46 NOX
Q4 47 42 GND NOX
RB1 43 41 2000
RB2 40 42 2000
CB1 Vcco 41 0.5E-12
CB2 42 GND 1E-12
RO1 46 44 1
D4 44 Q DX
RO2 47 Q 500
EO1 97 43 (20,GND) 1
EO2 40 GND (20,GND) 1
*
* Q NOT Output
*
Q5 Vcco 61 66 NOX
Q6 67 62 GND NOX
RB3 63 61 2000
RB4 60 62 2000
CB3 Vcco 61 0.5E-12
CB4 62 GND 1E-12
RO3 66 64 1
D5 64 QNOT DX
RO4 67 QNOT 500
EO3 63 GND (20,GND) 1
EO4 97 60 (20,GND) 1
*
* MODELS
*
.MODEL PIX PNP(BF=100,IS=1E-16)
.MODEL NOX NPN(BF=100,VAF=130,IS=1E-14)
.MODEL DX D(IS=1E-14)
.MODEL SLATCH1 VSWITCH(ROFF=1E6,RON=500,VOFF=2.1,VON=1.4)
.ENDS ADCMP573_new


Best Regards,
Sham