Hi,
I am working on an application using LT1210 op-amps. I simulated the Zol, open-loop trans-resistance of the op-amp in the LTSpice.
It is close to the the datasheet spec of 260KOhm. The simulation resulted in a ZOL of 220 KOhm.
However, Zol has a first order transfer function in my simulation when using the LT1210 model from LTSpice. In my application, I need a higher order model to match the time-constants of the simulation with the real application.
In the simulation, the system dynamics are much slower than the actual application.
Could you please let me know what I can change in the LT1210 model to make it a higher order model. Please help!!
Thanks,
Sre
.subckt LT1210 1 2 3 4 5 6
R2 N010 N014 10K noiseless
R3 N014 N018 10K noiseless
Q1 N005 N010 2 0 N temp=27
Q2 N019 N018 2 0 P temp=27
M1 3 N011 N013 N013 N temp=27
M2 4 N011 N013 N013 P temp=27
C4 3 5 2.2p
C5 5 4 2.2p
D1 3 N010 1uA m=81
R19 3 N005 100 noiseless
R20 N019 4 100 noiseless
G5 0 N006 N005 3 12
G6 N006 0 4 N019 12
D3 N016 3 X
D4 4 N016 X
C2 3 2 1p
C6 3 1 1p
C7 2 4 1p
C8 1 4 1p
A2 0 0 1 1 1 1 N014 1 OTA G=.1 Rout=10 Vhigh=100 Vlow=-100 en=3n Linear enk=30
A3 0 1 0 0 0 0 0 0 OTA in=2p ink=600
A4 0 2 0 0 0 0 0 0 OTA in=40p ink=30
D2 N018 4 1uA m=81
A5 N007 0 0 0 0 0 N016 0 OTA G=555u Iout=10u Vlow=-1e308 Vhigh=1e308
C3 0 N006 .7p Rpar=1K noiseless
D5 N013 N011 Y
C9 N008 N007 .1p Rser=30K Cpar=.01p noiseless
G1 0 N007 N006 0 20m
R1 N007 0 50 noiseless
G2 0 N008 N016 0 20m
R5 N008 0 50 noiseless
G3 0 N011 N015 0 10
C1 N011 0 .007p Rpar=100K noiseless
D6 N008 N015 S
C11 N015 0 7p
L1 N013 5 .03 Rser=.9 Rpar=10 Cpar=250p noiseless
C13 3 N013 2.2p
C14 N013 4 2.2p
R7 6 N008 25 noiseless
D7 3 4 Q
C15 3 6 2.2p
C16 6 4 2.2p
.model N NPN(Cje=.25p Cjc=.25p noiseless)
.model P PNP(Cje=.25p Cjc=.25p noiseless)
.model N VDMOS(Vto=-.15 Kp=2)
.model P VDMOS(Vto=.15 Kp=2 pchan)
.model 1uA D(Ron=100K epsilon=.5 Ilimit=1u noiseless)
.model X D(Ron=1K Roff=.82G epsilon=.5 Vfwd=-1.7 noiseless)
.model Y D(Ron=1K Roff=1G epsilon=.5 revepsilon=.5 Vfwd=1 Vrev=1 noiseless)
.model S D(Ron=100 Roff=100 Ilimit=6m RevIlimit=6m Vrev=0 noiseless)
.model Q D(Ron=100 Ilimit=11.9m epsilon=2 noiseless)
.ends LT1210
*
