Products Mentioned

AD8022 Production
The AD8022 consists of two low noise, high speed, voltage feedback amplifiers. Each amplifier consumes only 4.0 mA of quiescent current, yet has only 2...
Datasheet
AD8022 on Analog.com

Thread Details

  • State Not Answered
  • Replies 4 replies
  • Subscribers 36 subscribers
  • Views 1148 views
  • Users 0 members are here
Options 

        

            Post
             Go back to editing
        

    

    


    

    









		


















	
	
			
	
			
		
	
	
		

	    
	    
	    		
AD8022 Spice Noise Model

		
	
				

			

									
					    bluey
					
							

            
            			
				
									
											
			
			
				
			
			
			    	
			                    
                
				                on May 22, 2022 
				
			
			
		

		
		                     
				
        		

		    
		    		    

		      		            		        
Category: Software

    		        		            		    
Product Number:  AD8022 

    		        		    		    

		    		    
		    			

			    
Is there an update for the AD8022 spice model that fixes the noise? The model on the website shows the opamp having hundred's of nV per rtHz noise. This issue was brought up in 2017:  AD8022 spice model noise problem but it seems the spice model on the website has not been updated (last update 2012).


Also, tried the spice model attached in that forum post, it has much lower noise, but too low. With the op-amp as a unity gain buffer and a ground for the plus pin input, I get 1nV/rtHz of noise but the datasheet has 2.5nV/rtHz.


Thanks,


Ben

			

			
									
		                             
                        

    

                                            
                 Operational Amplifiers (Op Amps)
                
                                                    
                 amplifiers
                
                                                    
                 software
                
                                                    
                 AD8022
                
                                                    
                 spice
                
                                        
                                            
                
                
                                        
                                            
                
                
                                        
                                            
                
                
                                
                    Show More
            

    
    
		


				
				        
        		

			
						
									
												
			
			
                        
                                    
                        
                        
                        
            
			            
						
						
			
			
			
			
		


        
        
        
    
					

			





















	

	

					



			


				
	









	
    
	

  • 
	
    



	
		
	
	



    
	
    
		
    
							
					
    
		
    
		    
		    		    
			
				
									
							        
			
			
			
    •  Analog Employees  
    
            
						
                            
            
            				
            
                on May 23, 2022 10:20 PM
            
            
						
			            		
    
		
										0
					
	
    

		
		
    
		
    
                                
                                                            
    
					
    Hi, 
    

    We'll check the model and get back to you.
    
			
    

		
			
	      

		
		
	
    
	
    
		
    
			
		
    
	
    
	
    
		
						
						
				
						
				
				
		
		
    
			
		
    
	
    

    

    • 

	

  • 
	
    



	
		
	
	



    
	
    
		
    
							
					
    
		
    
		    
		    		    
			
				
									
							        
			
			
			
    •  Analog Employees  
    
            
						
                            
            
            				
            
                on May 30, 2022 9:10 PM
            
            
												
						in reply to gdsalas
					
										
			            		
    
		
										0
					
	
    

		
		
    
		
    
                                
                                                            
    
					
    Hi Ben, 
    

    I ran a simulation using the model attached in the forum for VS=+/-12V and VS=+/-2.5V and got 2.30nV/rtHz at f=100kHz. Can you share the simulator and circuit used? 
    

    Thanks, 
    

    Gerdan
     
    
			
    

		
			
	      

		
		
	
    
	
    
		
    
			
		
    
	
    
	
    
		
						
						
				
						
				
				
		
		
    
			
		
    
	
    

    

    • 

	

  • 
	
    



	
		
	
	



    
	
    
		
    
							
					
    
		
    
		    
		    		    
			
				
									
							        
			
			
			
            
						
                            
            
            				
            
                on May 31, 2022 8:29 AM
            
            
												
						in reply to gdsalas
					
										
			            		
    
		
										0
					
	
    

		
		
    
		
    
                                
                                                            
    
					
    No problem. Attached is my .asc for the LTSpice sim. For some reason it won't let me upload the .asy file I'm using for the ad8022, so I've put it inline as code:
    

    Version 4
SymbolType CELL
LINE Normal -32 32 32 64
LINE Normal -32 96 32 64
LINE Normal -32 32 -32 96
LINE Normal -28 48 -20 48
LINE Normal -28 80 -20 80
LINE Normal -24 84 -24 76
LINE Normal 0 32 0 48
LINE Normal 0 96 0 80
LINE Normal 4 44 12 44
LINE Normal 8 40 8 48
LINE Normal 4 84 12 84
LINE Normal 20 84 12 84
LINE Normal 16 72 16 80
WINDOW 0 16 32 Left 2
WINDOW 3 16 96 Left 2
SYMATTR Value AD8022
SYMATTR Prefix X
SYMATTR ModelFile ad8022b.cir
PIN -32 80 NONE 0
PINATTR PinName 100
PINATTR SpiceOrder 1
PIN -32 48 NONE 0
PINATTR PinName 101
PINATTR SpiceOrder 2
PIN 0 32 NONE 0
PINATTR PinName 102
PINATTR SpiceOrder 3
PIN 0 96 NONE 0
PINATTR PinName 103
PINATTR SpiceOrder 4
PIN 32 64 NONE 0
PINATTR PinName 104
PINATTR SpiceOrder 5
PIN 16 96 NONE 0
PINATTR PinName 106
PINATTR SpiceOrder 6
    

    

    AD8022Test.asc
    
			
    

		
			
	      

		
		
	
    
	
    
		
    
			
		
    
	
    
	
    
		
						
						
				
						
				
				
		
		
    
			
		
    
	
    

    

    • 

	

  • 
	
    



	
		
	
	



    
	
    
		
    
							
					
    
		
    
		    
		    		    
			
				
									
							        
			
			
			
    •  Analog Employees  
    
            
						
                            
            
            				
            
                on Jun 14, 2022 8:58 PM
            
            
												
						in reply to bluey
					
										
			            		
    
		
										0
					
	
    

		
		
    
		
    
                                
                                                            
    
					
    Hi Ben, 
    

    Re-created your test using the .cir from the forum and still got 2.3nV/rtHz. I noticed that the referenced model file in the code is  .
    

    I've attached the .cir from the forum here. Can you try using this model instead?
    

    



    
    
    
        Fullscreen
        AD8022.txt
        Download
    
    
    
    *AD8022 Macro-model
*Function:Amplifier
*
*Revision History:
*Rev.2.1 Feb 2017-ZZ
*Copyright 2017 by Analog Devices
*
*Refer to http://www.analog.com/Analog_Root/static/techSupport/designTools/spicemodels/license
*for License Statement. Use of this model indicates your acceptance
*of the terms and provisions in the License Staement.
*
*Tested on MultSIm, SiMetrix(NGSpice), PSpice
*
*Not modeled: Distortion, PSRR, Overload Recovery,
*             Shutdown Turn On/Turn Off time
*
*Parameters modeled include:
*   Vos, Ibias, Input CM limits and Typ output voltge swing over full supply range,
*   Open Loop Gain & Phase, Slew Rate, Output current limits, Voltage & Current Noise over temp,
*   Capacitive load drive, Quiescent and dynamic supply currents,
*   Shut Down pin functionality where applicable,
*   Single supply & offset supply functionality.
*
*Node Assignments
*               Non-Inverting Input
*               |   Inverting Input
*               |   |   Positive supply
*               |   |   |   Negative supply
*               |   |   |   |   Output
*               |   |   |   |   |
.Subckt AD8022 100 101 102 103 104
*
***Power Supplies***
Rz1	102	1020	Rideal	1e-6
Rz2	103	1030	Rideal	1e-6
Ibias	1020	1030	dc	0.4e-3
DzPS	98	1020	diode
Iquies	1020	98	dc	3.6e-3
S1	98	1030	106	113	Switch
R1	1020	99	Rideal	1e7
R2	99	1030	Rideal	1e7
e1	111	110	1020	110	1
e2	110	112	110	1030	1
e3	110	0	99	0	1
*
*
***Inputs***
S2	1	100	106	113	Switch
S3	9	101	106	113	Switch
VOS	1	2	dc	1.5e-3
IbiasP	110	2	dc	2.5e-6
IbiasN	110	9	dc	2.5e-6
RinCMP	110	2	Rideal	7e6
RinCMN	9	110	Rideal	7e6
CinCMP	110	2	0.8e-12
CinCMN	9	110	0.8e-12
IOS	9	2	0.12e-6
RinDiff	9	2	Rideal	20e3
CinDiff	9	2	0.8e-12
*
*
***Non-Inverting Input with Clamp***
g1	3	110	110	2	0.001
RInP	3	110	Rideal	1e3
RX1	40	3	Rideal	0.001
DInP	40	41	diode
DInN	42	40	diode
VinP	111	41	dc	0.71
VinN	42	112	dc	1.21
*
*
***Vnoise***
hVn	6	5	Vmeas1	707.10678
Vmeas1	20	110	DC	0
Vvn	21	110	dc	0.65
Dvn	21	20	DVnoisy
hVn1	6	7	Vmeas2	707.10678
Vmeas2	22	110	dc	0
Vvn1	23	110	dc	0.65
Dvn1	23	22	DVnoisy
*
*
***Inoise***
FnIN	9	110	Vmeas3	0.7071068
Vmeas3	51	110	dc	0
VnIN	50	110	dc	0.65
DnIN	50	51	DINnoisy
FnIN1	110	9	Vmeas4	0.7071068
Vmeas4	53	110	dc	0
VnIN1	52	110	dc	0.65
DnIN1	52	53	DINnoisy
*
FnIP	2	110	Vmeas5	0.7071068
Vmeas5	31	110	dc	0
VnIP	30	110	dc	0.65
DnIP	30	31	DIPnoisy
FnIP1	110	2	Vmeas6	0.7071068
Vmeas6	33	110	dc	0
VnIP1	32	110	dc	0.65
DnIP1	32	33	DIPnoisy
*
*
***CMRR***
RcmrrP	3	10	Rideal	1e12
RcmrrN	10	9	Rideal	1e12
g10	11	110	10	110	-1e-10
Lcmrr	11	12	1e-12
Rcmrr	12	110	Rideal	1e3
e4	5	3	11	110	1
*
*
***Power Down***
VPD	111	80	dc	2
VPD1	81	0	dc	1.5
RPD	111	106	Rideal	0.286e6
ePD	80	113	82	0	1
RDP1	82	0	Rideal	1e3
CPD	82	0	1e-10
S5	81	82	83	113	Switch
CDP1	83	0	1e-12
RPD2	106	83	1e6
*
*
***Feedback Pin***
*RF	105	104	Rideal	0.001
*
*
***VFB Stage***
g200	200	110	7	9	1
R200	200	110	Rideal	250
DzSlewP	201	200	DzSlewP
DzSlewN	201	110	DzSlewN
*
*
***Dominant Pole at 26 Hz***
g210	210	110	200	110	2.6014e-6
R210	210	110	Rideal	6.12e6
C210	210	110	1e-012
*
*
***Output Voltage Clamp-1***
RX2	60	210	Rideal	0.001
DzVoutP	61	60	DzVoutP
DzVoutN	60	62	DzVoutN
DVoutP	61	63	diode
DVoutN	64	62	diode
VoutP	65	63	dc	6.997
VoutN	64	66	dc	6.997
e60	65	110	111	110	1.052
e61	66	110	112	110	1.052
*
*
***Pole at 88MHz***
g220	220	110	210	110	0.001
R220	220	110	Rideal	1000
C220	220	110	1.8086e-12
*
***Buffer***
g230	230	110	220	110	0.001
R230	230	110	Rideal	1000
*
***Buffer***
g240	240	110	230	110	0.001
R240	240	110	Rideal	1000
*
***Buffer***
g245	245	110	240	110	0.001
R245	245	110	Rideal	1000
*
***Buffer***
g250	250	110	245	110	0.001
R250	250	110	Rideal	1000
*
***Buffer***
g255	255	110	250	110	0.001
R255	255	110	Rideal	1000
*
***Buffer***
g260	260	110	255	110	0.001
R260	260	110	Rideal	1000
*
***Buffer***
g265	265	110	260	110	0.001
R265	265	110	Rideal	1000
*
***Buffer***
g270	270	110	265	110	0.001
R270	270	110	Rideal	1000
*
***Buffer***
e280	280	110	270	110	1
R280	280	285	Rideal	10
*
***Peak: f=360MHz, Zeta=1.8, Gain=15dB***
e290	290	110	285	110	1
R290	290	292	Rideal	10
L290	290	291	1.228e-9
C290	291	292	159.155e-12
R291	292	110	Rideal	2.163
e295	295	110	292	110	5.6234
*
*
***Output Stage***
g300	300	110	295	110	0.001
R300	300	110	Rideal	1000
e301	301	110	300	110	1
Rout	302	303	Rideal	 26
Lout	303	310	 3e-9
Cout	310	110	 6.3e-12
*
*
***Output Current Limit***
H1	301	304	Vsense1	100
Vsense1	301	302	dc	0
VIoutP	305	304	dc	9.336
VIoutN	304	306	dc	9.336
DIoutP	307	305	diode
DIoutN	306	307	diode
Rx3	307	300	Rideal	0.001
*
*
***Output Clamp-2***
VoutP1	111	73	dc	2.085
VoutN1	74	112	dc	2.085
DVoutP1	75	73	diode
DVoutN1	74	75	diode
RX4	75	310	Rideal	0.001
*
*
***Supply Currents***
FIoVcc	314	110	Vmeas8	1
Vmeas8	310	311	dc	0
R314	110	314	Rideal	1e9
DzOVcc	110	314	diode
DOVcc	102	314	diode
RX5	311	312	Rideal	0.001
FIoVee	315	110	Vmeas9	1
Vmeas9	312	313	dc	0
R315	315	110	Rideal	1e9
DzOVee	315	110	diode
DOVee	315	103	diode
*
*
***Output Switch***
S4	104	313	106	113	Switch
*
*
*** Common Models ***
.model	diode	d(bv=100)
.model	Switch	vswitch(Von=1.505,Voff=1.495,ron=0.001,roff=1e6)
.model	DzVoutP	D(BV=4.3)
.model	DzVoutN	D(BV=4.3)
.model	DzSlewP	D(BV=19.696)
.model	DzSlewN	D(BV=19.696)
.model	DVnoisy	D(IS=1.95e-16 KF=9.99e-16)
.model	DINnoisy	D(IS=5.42e-17 KF=4.45e-16)
.model	DIPnoisy	D(IS=5.42e-17 KF=4.45e-16)
.model	Rideal	res(T_ABS=-273)
*
.ends

    

    


    
			
    

		
			
	      

		
		
	
    
	
    
		
    
			
		
    
	
    
	
    
		
						
						
				
						
				
				
		
		
    
			
		
    
	
    

    

    •